24-Intervalos e Gr\303\241ficos de Retas Num\303\251ricas
Os gr\303\241ficos de retas num\303\251ricas de intervalos finitos e infinitos. esta \303\241rea de trabalho tamb\303\251m cobre a nota\303\247\303\243o de intervalo e conjuntos mais complexos.
<Text-field style="Heading 1" layout="Heading 1"><Font encoding="UTF-8">C\303\263digo </Font></Text-field>
restart: with(plots):
intfin := proc( a, b, leq, req )
#description "plot a finite interval on a number line";
local r, M, v1, v2, wid, bar, Axesplot, leftpt, rightpt, pt_color,
leftend, rightend, LT, RT, IT, textpos, lt, rt;
r := b-a ;
M := evalf( 1.2 * max( b-a, abs(a), abs(b) ) );
v1 := [a, 0];
v2 := [b, 0];
wid := ceil( M/15) ;
bar := arrow( v1, v2,
shape = double_arrow, color = red , difference = true,
width = wid, head_width = 0, head_length = 0):
if( leq ) then lt := `[`; else lt := `(`; fi;
if( req ) then rt := `]`; else rt := `)`; fi;
textpos := max(wid, 2) ;
LT := textplot( [a, textpos, a] ):
RT := textplot( [b, textpos, b] ):
IT := textplot( [(a+b)/2, textpos + wid, cat(lt,a,`,`,b,rt)], color = green ):
leftend := min( a - 2*wid, 0);
rightend := max( b + 2*wid, 0);
Axesplot := plot( 0, x = leftend..rightend ,
y = (-wid)..(2*wid), axes = none, thickness = 2,
scaling = constrained, tickmarks = [1,1] ):
if( leq ) then pt_color := red; else pt_color := white; fi;
leftpt := plottools[disk]([ a, 0], wid/2, color=pt_color):
if( req ) then pt_color := red; else pt_color := white; fi;
rightpt := plottools[disk]([ b, 0], wid/2, color=pt_color ):
display( leftpt, rightpt, bar, Axesplot, LT, RT, IT );
end proc:
#__________________________________________________________
intinfr := proc(a, leq )
# description "plot an infinite interval going to +inf";
local bb, r, M, v1, v2, wid, bar, Axesplot, textpos,
leftpt, rightpt, pt_color, leftend, rightend, LT, RT, IT,lt;
bb := max( 3*abs(a), 5) ;
r := bb-a;
M := evalf(1.2* max( abs(r), abs(a)));
v1 := [a, 0];
v2 := [bb, 0];
wid := ceil( M/15);
bar := arrow( v1, v2,
shape = double_arrow, color = red , difference = true,
width = wid, head_width = 1.8*wid, head_length = 1.2*wid):
if( leq ) then lt := `[`; else lt := `(`; fi;
textpos := max(wid, 3) ;
LT := textplot( [a, textpos, a] ):
RT := textplot( [bb, textpos, `Infinity`] ):
IT := textplot( [(a+bb)/2, textpos + wid, cat(lt,a,`, infinty)`)], color = green ):
leftend := min( 0, a*1.5);
rightend := max( 0, bb);
Axesplot := plot( 0, x = leftend..rightend ,
y = (-wid)..(3*wid), axes = none, thickness = 2,
scaling = constrained, tickmarks = [1,1] ):
if( leq ) then pt_color := red; else pt_color := white; fi;
leftpt := plottools[disk]([ a, 0], wid/2, color=pt_color):
display( leftpt, bar, Axesplot, LT, RT, IT );
end proc:
#__________________________________________________________
intinfl := proc( b, req )
# description "plot a infinite interval going to -inf";
local aa, bb, r, M, v1, v2, wid, bar, Axesplot,textpos,
leftpt, rightpt, pt_color, leftend, rightend, LT, RT, IT, rt;
aa := min( -3*abs(b), -5);
r := b-aa;
M := evalf(1.2*max( abs(r), abs(b) ));
v1 := [aa, 0];
v2 := [b, 0];
wid := ceil( M/15);
bar := arrow( v2, v1,
shape = double_arrow, color = red , difference = true,
width = wid, head_width = 1.8*wid, head_length = 1.2*wid):
textpos := max(wid, 3) ;
if( req ) then rt := `]`; else rt := `)`; fi;
LT := textplot( [aa, textpos, `-Infinity`] ):
RT := textplot( [b, textpos, b] ):
IT := textplot( [(aa+b)/2, textpos + wid, cat(`(-infinity,`,b,rt)], color = green ):
leftend := min( 0, aa);
rightend := max( 0, b*1.5);
Axesplot := plot( 0, x = leftend..rightend ,
y = (-wid)..(3*wid), axes = none, thickness = 2,
scaling = constrained, tickmarks = [1,1] ):
if( req ) then pt_color := red; else pt_color := white; fi;
rightpt := plottools[disk]([ b, 0], wid/2, color=pt_color):
display( rightpt, bar, Axesplot, LT, RT , IT);
end proc:
#__________________________________________________________
intall := proc()
#description "plot a infinite interval of all real numbers ";
local a, b, v1, v2, wid, bar1, bar2, LT, RT, Axesplot ;
a := -25; b := 25;
v1 := [a, 0];
v2 := [b, 0];
wid := ceil( (b-a)/15);
bar1 := arrow( v1,
shape = double_arrow, color = red , difference = false,
width = wid, head_width = 1.8*wid, head_length = 1.2*wid):
bar2 := arrow( v2,
shape = double_arrow, color = red , difference = false,
width = wid, head_width = 1.8*wid, head_length = 1.2*wid):
LT := textplot( [a, max( wid, 6), `-Infinity`] ):
RT := textplot( [b, max( wid, 6), `Infinity`] ):
Axesplot := plot( 0, x = a..b ,
y = (-wid)..(3*wid), axes = none, thickness = 2,
scaling = constrained, tickmarks = [1,1] ):
display( bar1, bar2, Axesplot, LT, RT );
end proc:
#__________________________________________________________
#__________________________________________________________
intv := proc( expr1, expr2 )
# description "plot a infinite interval going to -inf";
local a, b, leq, req;
if type( expr1, `<=`) then leq := true; else leq := false; fi;
if type( expr2, `<=`) then req := true; else req := false; fi;
a := lhs( expr1); b := rhs( expr2);
if( abs(a) <> infinity)
then if( abs(b) <> infinity) then intfin( a,b, leq, req );
else intinfr( a, leq); fi;
else if( abs(b) <> infinity) then intinfl( b, req);
else intall(); fi;
fi;
end proc:
<Text-field style="Heading 1" layout="Heading 1"><Font encoding="UTF-8">Uni\303\265es e Conjuntos Mais Complexos </Font></Text-field>
Tamb\303\251m podemos formar conjuntos mais complexos.
display( intv( -infinity <x, x < -10 ), intv( 10 < x, x < infinity ) );
No futuro, voc\303\252 pode vir a resolver uma inequa\303\247\303\243o como essa, a qual tamb\303\251m pode ser um gr\303\241fico.
solve( (x-3)*(x-1)*(x+4) > 0, x);
display( intv( -4 < x, x < 1 ), intv( 3 < x, x < infinity ) );
Veja esse exemplo. Observe o m\303\251todo do Maple de representar um intervalo em alcance real "real range".
solve( ((x-1)*(x+7))/ (x^2 - 4) >= 0, x);
display( intv( -infinity <= x, x < -7 ),
intv( -2 < x, x <= 1 ),
intv( 2 < x, x < infinity ) );