Gráficos de funções (uma variável)

Antes de começar a compilar os comandos desta seção é recomendável limpar a memória utilizada pelo Maple compilando o comando seguinte.

> restart;

Os dois sistemas de coordenadas mais utilizados para o traçado de curvas, ou de gráficos de funções, no plano são o sistema de coordenadas cartesianas e o sistema de coordenadas polares. Explicaremos como esboçar parte de gráficos utilizando esses dois sistemas.

Em coordenadas cartesianas

Para visualizar partes de gráficos de funções devemos primeiramente defini-las. Por exemplo:

> f:=t->4*t^3+2;
g:=t->sin(t);
h:=t->t^2;

>

O Maple é capaz de plotar uma quantidade bem razoável de pontos do gráfico de uma função, o que permite uma visualização bem interessante. Deve-se utilizar o comando plot(....) , onde dentro do parêntesis coloca-se o nome da função e o domínio referente a região do gráfico que vai ser mostrada. Por exemplo, para ver a região do gráfico da função com domínio entre e digita-se:

> plot(f(t),t=-1 .. -0.5);

>

É indiferente trocar o nome da variável, verifque abaixo.

> plot(f(x),x=-1..-0.5);

>

Para ver regiões dos gráficos das funções , e num mesmo quadro deve-se colocar como argumento do comando plot uma lista ( limitada entre colchetes ) com as funções desejadas e o domínio solicitado, por exemplo:

> plot([f(t),g(t),h(t)],t=-1..-0.5);

>

Outra opção para obter o mesmo resultado é atribuir nomes aos gráficos e depois mostrá-los com o comando plots[display] . Neste caso, quando atribuido um nome ao gráfico o Maple exibe a lista de pontos plotados. Para se trabalhar com um arquivo mais limpo, colocamos no final do comando de atribuição de nome o sinal DOIS PONTOS. Este último permite que o Maple compile a linha e não execute sua saída de video, ao final do comando plots[display] colocamos normalmente o sinal PONTO E VÍRGULA. Observe-se que este tipo de procedimento plota todos os gráficos com a mesma cor.

> a:=plot(f(x),x=-1..-0.5):
b:=plot(g(x),x=-1..-0.5):
c:=plot(h(x),x=-1..-0.5):
plots[display]({a,b,c});

>

Quando o Maple plota vários gráficos num mesmo quadro, automaticamente fornece a cada um deles uma cor diferente. Se o leitor quiser atribuir uma cor específica a certo gráfico pode usar comandos como os abaixo:

> a:=plot(f(x),x=-1..-0.5,color=red):
b:=plot(g(x),x=-1..-0.5,color=blue):
c:=plot(h(x),x=-1..-0.5,color=gray):
plots[display]({a,b,c});

>

Ou ainda, para o mesmo resultado, pode-se colocar uma lista de funções e uma lista de cores no opcional color .

> plot([f(x),g(x),h(x)],x=-1..0.5,
color=[gold,red,blue]);

>

Finalmente se o leitor desejar colocar lado a lado vários gráficos tem de definir uma matriz apropriada, com a quantidade de elementos igual à quantidade de gráficos e colocar em cada entrada da matriz um gráfico. Se a quantidade de gráficos for pequena pode-se usar vetores em vez de matrizes.

Por exemplo para colocar três gráficos lado a lado pode-se usar um vetor de três entradas.

> with(plots):
A := array(1..3):
A[1] := plot(sin(x),x=-Pi..Pi,axes=framed):
A[2] := plot(cos(x),x=-Pi..Pi,axes=boxed,style=point):
A[3] := plot(2*x,x=-Pi..Pi):
display(A);

Warning, the name changecoords has been redefined

>

Em coordenadas polares

Existe um pacote no Maple chamado plots que permite ao usuário plotar gráfico de funções em coordenadas polares. Podemos carregar este pacote com o comando with(plots). Pode-se também usar o comando para plotar gráficos em coordenadas polares sem carregar todo o pacote plots, para isso utiliza-se a seguinte sintaxe plots[polarplot](...) .