Opcionais do comando plot

Existem duas maneiras de modificar os gráficos mostrados pelo Maple utilizando opcionais. Elas são explicadas nas duas subseções abaixo.

A primeira delas é através do menú.

A segunda é digitando os opcionais e seus valores no comando plot . Os opcionais do comando plot devem ser colocados após o domínio da função, do seguinte modo: plot(função,domínio, opcional1,opcional2,...) .

Nesta seção são descritos os principais opcionais.

Para descarregar a memória utilizada pelo Maple compile o comando abaixo antes de iniciar o estudo da seção.

> restart;

>

Via menu

No menu principal do Maple existe a opção options . Dentro desta, existe a opção plot display . Se o leitor escolher dentro da última, a opção inline , os gráficos serão mostrados dentro da folha de trabalho. Se o leitor escolher a opção window , os gráficos serão mostrados em janelas separadas. A escolha mais natural e mais agradável para se trabalhar é usando a opção inline .

Assumindo que a escolha do tipo de saída dos gráficos seja inline , existe um modo de selecionar opcionais fazendo surgir o menu especial clicando sobre a figura do gráfico. Este menu aparece logo abaixo do menu principal. Com ele pode-se fazer a escolha de vários opcionais através de seus botões.
Opcionais também podem ser escolhidos clicando-se sobre o gráfico com o botão direito do mouse.
Em versões mais antigas do Maple, após a escolha dos opcionais, é necessário clicar no menu do gráfico a tecla identificada com a letra "R" .

Convém observar que o gráfico estando ativado, pode-se modificar seu tamanho, redimensionando-o como uma janela qualquer do ambiente windows.

As opções que não se encontram neste menu podem ser modificadas através da opção style do menu principal.

Experimente no comando abaixo:

> plot(x^3+13*x^2-1,x=-15..7);

>

Via digitação

Listamos aqui algumas explicações que com certeza capacitarão o leitor a construir gráficos com legendas, índices, títulos, etc. Isto possibilitará facilmente a construção de ilustrações para trabalhos científicos, notas de aula, e outras atividades.

vertical range

Este opcional permite que o leitor estipule a abrangência que deve aparecer no eixo dos "yy". Pode ser utilizado quando se quer saber se para um dado intervalo do domínio a função atinge certos valores. Por exemplo, será que a função atinge valores entre 45 e 50 quando x pertence ao intervalo [7,9]? A resposta pode ser obtida com o comando:

> f:=x->(x^2)*sin(x);
plot(f(x),x=7..9,y=45..50);

>

Após analisar o gráfico podemos responder que sim, e isto acontece em dois subintervalos.

Observe que o nome que se dá a variável dependente pode ser qualquer um, nos exemplos abaixo são utilizados vários nomes para os números do eixo vertical e o resultado mostrado é o mesmo.

> plot(f(x),x=7..9,z=45..50);

> plot(f(x),x=7..9,lucro=45..50);

> plot(f(x),x=7..9,MHz=45..50);

>

Outros exemplos:

> plot(sin(x),x=0..9,alt=-0.5..0.5);

> plot(sin(x),x=0..9,img=-0.5..0.5);

> plot(sin(theta),theta=0..9,resto=-0.5..0.5);

>

axes

Este comando permite a escolha de diferentes tipos de eixos na apresentação do gráfico, as quatro opções estão nos exemplos abaixo.

> f:=x->sin(x);
plot(f(x),x=-2..2,axes=frame);

> f:=x->sin(x);
plot(f(x),x=-2..2,axes=boxed);

> f:=x->sin(x);
plot(f(x),x=-2..2,axes=normal);

> f:=x->sin(x);
plot(f(x),x=-2..2,axes=none);

>

axesfont

Este comando permite escolher o tipo e o tamanho de fonte a ser usado nas marcações dos eixos. Existem quatro famílias disponíveis, são elas: TIMES, COURIER, HELVETICA e SYMBOL. Os estilos disponíveis para TIMES são ROMAN, BOLD, ITALIC e BOLDITALIC. Os estilos disponíveis para COURIER e HELVETICA são BOLD, OBLIQUE, BOLDOBLIQUE ou padrão. Não existem estilos para SYMBOL. No final do opcional pode-se colocar o tamanho da fonte a ser usada.

Apresentamos abaixo alguns exemplos.

Observação: As opções devem ser escritas com MAIÚSCULAS.

> f:=x->sin(x);
plot(f(x),x=-2..2);

> f:=x->sin(x);
plot(f(x),x=-2..2,axesfont=[TIMES,ITALIC,18]);

> f:=x->sin(x);
plot(f(x),x=-2..2,axesfont=[HELVETICA,BOLD,14]);

> f:=x->sin(x);
plot(f(x),x=-2..2,axesfont=[COURIER,BOLDOBLIQUE,14]);

> f:=x->sin(x);
plot(f(x),x=-2..2,axesfont=[SYMBOL,18]);

>

color

Este opcional permite atribuir ao traço do gráfico cores já pré-estabelecidas ou mixadas através do sistema RGB (red,green,blue). A relação de cores pré-estabelecidas está a seguir.

aquamarine black blue navy coral cyan
brown gold green gray grey khaki
magenta maroon orange pink plum red
sienna tan turquoise violet wheat white
yellow

Para usar o sistema RGB deve-se usar a sintaxe

color=COLOR(RGB,a,b,c)

onde a, b e c são números entre 0 e 1.

Seguem vários exemplos.

> f:=x->sin(x);
plot(f(x),x=-2..2,color=green);

> f:=x->sin(x);
plot(f(x),x=-2..2,color=coral);

> f:=x->sin(x);
plot(f(x),x=-2..2,color=COLOR(RGB,0,0.7,0.4));

> f:=x->sin(x);
plot(f(x),x=-2..2,color=COLOR(RGB,1,0.5,0));

>

discont

Este opcional é importante quando se está trabalhando com funções definidas por partes. Ele permite um refinamento do algorítmo usado pelo Maple permitindo identificar descontinuidades do tipo "salto" nos gráficos.

Segue um exemplo onde acontece tal situação.

Primeiramente definimos uma função através de quatro sentenças.

> g:=x->piecewise(x<0,2*x,0<=x and x<Pi/2,sin(x),Pi/2<=x and x<3,1,3<x,-x+5);

>

Para verficar se a definição está correta é sempre bom pedir ao Maple a expressão da função numa variável. Fazemos isso abaixo.

> g(x);

>

Feita a verificação, vamos mostrar o gráfico sobre o intervalo [-1, 5].

> plot(g(x),x=-1..5);

>

Existe uma descontinuidade sobre o ponto x=3 . O limite de f(x) quando x tende a 3 pela esquerda é igual a 1 e quando x tende a 3 pela direita é igual a 2 . Mas a rotina da programação do Maple que constrói o gráfico não detecta esse comportamento da função.

Nessas situações, quando o usuário se deparar com partes de um gráfico que são muito verticais, é aconselhável utilizar o opcional discont=true. Este opcional permite um refinamento na rotina que passa a detectar este tipo de descontinuidade.

Veja o comando abaixo, onde colocamos o opcional.

> plot(g(x),x=-1..5,discont=true);

>

Um outro exemplo onde deve-se usar este opcional está a seguir.

> h:=x->1/x;
plot(h(x),x=-2..2,y=-9..9);
plot(h(x),x=-2..2,y=-9..9,discont=true);

>

labels

Com a sintaxe labels=[nome1, nome2] pode-se atribuir nomes aos eixos coordenados. Este opcional tem muita utilidade quando as variáveis tem significado.

Por exemplo, para mostrar um gráfico onde a variável independente é o tempo e a variável dependente é a velocidade pode-se fazer o seguinte:

> f:=x->sin(x);
plot(f(x),x=0..2,labels=[tempo,veloc]);

>

linestyle

O comando linestyle=número permite que o leitor escolha entre os diferentes tipos de linha atribuindo números de 1 até 4. Os diferentes tipos ficarão esclarecidos através dos exemplos a seguir.

> f:=x->sin(x);
plot(f(x),x=0..2,linestyle=1);

> plot(f(x),x=0..2,linestyle=2);

> plot(f(x),x=0..2,linestyle=3);

> plot(f(x),x=0..2,linestyle=4);

>

style

Este opcional permite que o leitor possa optar por trocar o estilo do gráfico de linhas para pontos, por exemplo.

> f:=x->sin(x);
plot(f(x),x=0..2,style=point);

> f:=x->sin(x);
plot(f(x),x=0..2,style=line);

>

O padrão do Maple é mostrar gráficos no estilo "line".

symbol

Este opcional permite escolher o tipo de símbolo usado na opção point . Podem ser box , cross , circle , point ou diamond .

> f:=x->sin(x);
plot(f(x),x=0..2,style=point,symbol=circle);

> plot(f(x),x=0..2,style=point,symbol=box);

>

title

Permite a colocação de título no gráfico. O bom para os usuários de Língua Portuguesa é que pode-se usar acentuação. Por exemplo.

> f:=x->sin(x);
plot(f(x),x=0..2,title=`gráfico da função altura`);

>

titlefont

Permite a escolha da fonte para o título do gráfico.

> f:=x->sin(x);
plot(f(x),x=0..2,title=`gráfico da função f(x)`,titlefont=[COURIER,BOLD,16]);

>

xtickmarks

Se for utilizado com a sintaxe xtickmarks=K , no eixo dos "xx" existirão não menos de K números marcados.

Se for utilizado com a sintaxe xtickmarks=[a,b,c,..,f] , no eixo dos "xx" existirão exatamente os números marcados.

Veja os seguintes exemplos.

No primeiro escolhemos marcar exatamente os pontos x=0, x=1.6 e x=1.9 no eixo dos "xx".

No segundo exemplo escolhemos marcar pelo menos 4 pontos dentro do intervalo [0, 2].

> f:=x->sin(x);
plot(f(x),x=0..2,xtickmarks=[0,1.6,1.9]);

> f:=x->sin(x);
plot(f(x),x=0..2,xtickmarks=4);

>

ytickmarks

Análogo ao anterior, para o eixo dos "yy".

> f:=x->sin(x);
plot(f(x),x=0..2,ytickmarks=[0.3,0.6,0.9]);

>