Calculo I

Lição 11:   Funções Implícitas e Diferenciação Implícita

Usualmente quando nós falamos de funções, nós estamos falando sobre funções explícitas na forma de y = f(x). Às Vezes nós temos ao invés de uma equação no x e y, por exemplo, x + y + xy = sin(x + y), que pode não ser resolvido por y. As soluções para esta equação são um conjunto de pontos {(x,y)} que implicitamente define uma relação entre o x e y que nós chamaremos de função implícita.  Funções Implícitas estão freqüentemente, mas não funciona realmente na definição estrita da palavra, porque elas freqüentemente têm valores  múltiplos de y para um valor único de x. Eles têm gráficos e derivadas entretanto.

Você está provavelmente familiarizado com algumas funções implícitas linearas de álgebra. Linhas em ponto-rampa e formulário padronizado (tal como y -3 = 2(x + 5) e 7x + 9y = 63) são ambos exemplos de funções implícitas desde que eles não estejam explicitamente resolvidas para y em termos de x. Esses podem ser resolvido para y bastante facilmente e convertido dentro das funções explícitas. Entretanto, muitas funções implícitas são impossíveis ou difíceis para converter para funções explícitas e devem ser deixadas na forma implícita.

Nossa primeira vontade de tarefa é, dada uma função implícita definida, nós podemos desenhar alguns pontos individuais no gráfico. Vamos  começar com   , e encontre todos os pontos onde x tem o valor 2.

>	restart; with(plots):

Warning, the name changecoords has been redefined

>	imp_fun := -4*x + 10*(x^2) * (y^(-2)) + y^2 = 11;

Nosso método consistirá de dois passos : primeiro, substituto ao valor de x, então resolve o resultado da equação em uma variável de y.

Nós substituimos x= 2 na equação implícita.
Isto fornece agente uma equação com um desconhecido

Nós resolvemos esta equação e obtemos soluções radicais exatas.
Nós podemos converter esses para respostas decimais desta forma.

>	subs( x = 2, imp_fun );

>	s := solve( % );

>	s := evalf( % );

DESENHANDO FUNÇÕES IMPLÍCITAS

Desenhando funções implícitas abre para cima um excitante mundo novo de possibilidades de desenho. Infelizmente, seu tempo  é completamente consumido para desenhar a maioria das funções implícitas feitas a mão - freqüentemente devolvemos eles efetivamente sem gráficos e sem ajudas tecnológicas. Afortunadamente, o Maple desenha essas funções efetivamente.

Ao invés de usar o comando plot , nós usamos o comando implicitplot . A primeira coisa você pode notar sobre funções implícitas é aquele maioria destas funções falham no teste de linha vertical.... miseravelmente! Aquela falha é uma das razões, eles estão assim interessantes. Aqui é uma elipse do tilted.

                                                    A Equação implícita  ,             uma série de  x,         e uma sérise de y.

>	implicitplot( x^2 + x*y + y^2 = 16, x = -5..5, y = -5..5, grid=[50,50] );

Algum das formas estão notavelmente simples

>	implicitplot( x^4 + 8*(x^3) + y^4 = 16, x = -12..10, y = -10..10, grid=[50,50],thickness = 2, color = brown, scaling = constrained);

Na outra mão, algumas funções podem estar extremamante complicadas. De Fato, isto é assim é tão complicado que nossa primeira tentativa somente dá uma sugestão para a complexidade. Por aumentar o número de pontos utilizados na produção do gráfico, uma grande quantidade de detalhes e sutilezas tornam-se visíveis.

>	implicitplot( x*y*cos(x^2 + y^2) = 1, x = -10..10, y = -10..10, grid=[30,30] );

>	implicitplot( x*y*cos(x^2 + y^2) = 1, x = -10..10, y = -10..10, grid=[80,80] );

Muitos desse gráficos são simétricos em vários caminhos. Esse são simétricos no eixo y.

>	implicitplot( x^2 + 1.5*y*x^2 + y^2 = 1, x = -10..10, y = -10..10, grid=[50,50] );

>	implicitplot( (x^2 + y^2 -2) = (.5 + y*x^2)^2 , x = -5..5, y = -5..5, grid=[100,100] );

Esse é simétrico no eixo x

>	implicitplot( -4*x + 10*(x^2) + (y^(-2)) + y^2 = 11, x = -5..5, y = -5..5, grid=[100,100] );

E este é simétrico nos eixos x e y.

>	implicitplot( x^2 - y^2 = x*y*sin(x*y), x = -4..4, y = -3..3, grid=[100,100] );

Esse gráfico é aparentemente simétrico a linha  y = -x.

>	implicitplot( x - y + sin(2.5*x*y) = sin(x) - sin(y) + sin(x*y), x = -5..5, y = -5..5, grid=[100,100] );

Alguns dos gráficos tem simetrias e modelos que não são fáceis de se descrever.

>	implicitplot( (x*y)*sin(y) = x*cos(x-y), x = -10..10, y = -10..10, grid=[100,100]);

Este tem as mais complexas sugestões que sugere um tipo mais complexo de simetria.

>	implicitplot( ln( (x + 7*sin(y))^2 ) = exp(y + 2*cos(x)) , x = -9..9, y = -12..3, grid=[100,100]);

Este gráfico criou o modelo Tesslation no plano.

>	implicitplot( sin(x + 2*sin(y) ) = cos( y + 3*cos(x)), x = -10..10, y = -10..10, grid=[100,100]);

C DERIVADAS IMPLÍCITAS

Somente como nós usamos o pedaço implicito do comando plot o desenho dessas funções, nós usamos o comando implicitdiff ao invés do comando diff  para achar as derivadas das funções implícitas.

>	implicitdiff( -4*x + 10*(x^2)*(y^(-2) ) + y^2 = 11, y, x);

O formato deste comando é uma equação que implicitamente define uma função, então as variáveis dependente e indepedente de y e x. Note que o resultado de pegar uma derivada implícita é uma função em ambos x e y.

Desde uma função implícita freqüentemente tem valores múltiplos de y para um valor único de x, há também linhas tangentes múltiplas. Neste exemplo, nós iremos através de vários passos construir não menos do que as linhas tangentes ao valor de x = 2.

Vamos começar pela a mesma funçaõ usada acima.

>	imp_fun := -4*x + 10*(x^2)*(y^(-2)) + y^2 =11;

Passo 1 : Escolha o valor de x  (c)

>

c := 2;

 Passo 2 : Ache o valor correspodente de y

>	s := evalf( solve( subs( x = c, imp_fun)));

Passo 3 : Ache o declive de cada ponto - lembre que a derivada implicita é a função de ambos x e y. Para x = c, existem quatro valores diferentes de y, e quatro diferentes declives.

>	m1 := evalf( subs ( { x = c, y = s[1] }, implicitdiff( imp_fun, y,x)));

>	m2 := evalf( subs ( { x = c, y = s[2] }, implicitdiff( imp_fun, y,x)));

>	m3 := evalf( subs ( { x = c, y = s[3] }, implicitdiff( imp_fun, y,x)));

>	m4 := evalf( subs ( { x = c, y = s[4] }, implicitdiff( imp_fun, y,x)));

Nós estamos descobrindo o valor do declive para cada um dos 4 valores de y por substituindo x = c, e y dentro das derivadas implícitas para cada caso.

Passo 4 : Desenhe a função e as suas 4 linhas tangentes.

>	implicitplot( {y - s[1] = m1*(x-c), y - s[2] = m2*(x-c), y - s[3] = m3*(x-c), y - s[4] = m4*(x-c), imp_fun }, x = -5..5, y = -5..5, grid=[100,100]);

>